
#
#  Set LaTeX environment variables and aliases
#  ('source' this file; assumes csh|tcsh)
#
# You might need to change some paths.
# In particular, you might want to replace/remove DOCDIR,
# and change TEXMFCNF.
#


unsetenv TEXDIR TEXSTYLES TEXINPUTS TEXFONTS TEXPKS
unsetenv XDVIFONTS PKFONTS TEXFORMATS TEXFONTDESC TEXPOOL TEXMFCNF
unalias dvips

#
#     adjust environment variables TEXDIR, PATH, and BIBINPUTS
#     and aliases 'sple' and 'splg', should you want to use them
#

setenv DOCDIR			`pwd`
setenv TEXDIR           /igd/a4/software/teTeX
setenv TEXMFCNF         ${DOCDIR}:

setenv PATH ${TEXDIR}/bin/mips-sgi-irix6.5:${PATH}

if ( $?MANPATH ) then
	setenv MANPATH ${TEXDIR}/man:${MANPATH}
endif

# set common path parts
setenv PATH ${PATH}:/igd/a4/software/gnuplot/bin


#
# A few aliases for convenience
#

alias xdvi	'xdvi -paper a4 -nopostscript -keep -s 7 -gsalpha'
alias dvilj	'dvilj -s26'

#  if you use \usepackage[a4paper,dvips]{geometry},
#  then you don't need to specify "-t a4" with dvips!
alias dvips	'dvips -o -r0'
#alias dvips	'dvips -t a4 -o -r0'

#  for spell checking with ispell
setenv INCLUDE_STRING '\include'
alias sple   'set f=\!^; /igd/a4/software/ispell/bin/ispell -t -B -m -b -d american -p $HOME/american.words ${f:r}.tex'
#  if your german text contains Umlauts like , then use the following alias
alias splg   'set f=\!^; /igd/a4/software/ispell/bin/ispell -t -B -m -b -d deutsch -T latin1 -p $HOME/deutsch.words ${f:r}.tex'
#  if your german text contains Umlauts like \"a, then use the following alias
#alias splg   'set f=\!^; /igd/a4/software/ispell/bin/ispell -t -B -m -b -d deutsch -p $HOME/deutsch.words ${f:r}.tex'

alias gr	'grep "\!*" *.tex'

alias fig	'(setenv XENVIRONMENT ${DOCDIR}/Fig-color.ad; set f=!^; xfig -specialtext -metric -startfontsize 10 -startpsFont Palatino-Roman -exportLanguage eepic -visual truecolor ${f:r}.fig)'

alias gv	'gv -watch -safer -pixmap'

if ( $?fignore ) then
	set fignore = ( $fignore .aux .bbl .log .blg )
else
	set fignore = ( .aux .bbl .log .blg )
endif


#
# A few complete's for convenience (only with tcsh)
#

if ( $shell =~ *tcsh ) then
	complete xdvi  'n/*/f:*.dvi/'
	complete dvips  'n/*/f:*.dvi/'
endif


